Вывод связанной информации по текущему объекту из списка

Часто возникает необходимость вывести связанную информацию для текущего объекта из списка, например, элемента справочника или документа. Это может быть остаток товара на складе, долг контрагента, автор документа, общая сумма и валюта документа и т.д. Рассмотрим, какие существуют способы решения этой задачи в 1С:Предприятии 8.1.

1-й способ. Колонка табличного поля в формы списка, связанная с реквизитом объекта или графой журнала документов. Хотя это простейший способ, но он не всегда применим, потому что связанная информация обычно берется из других объектов (таблиц).

2-й способ. Системная кнопка "Перейти" или подобные кнопки, разработанные программистом, вызывающие отчеты или другие окна со связанной информацией по текущему объекту. Неудобство данного способа заключается в том, что часто информация должна быть еще более доступна, т.е. прямо в этом же окне, без лишних щелчков мыши и других окон.

3-й способ. Обработчик события "ПриАктивизацииСтроки". Это самый желательный способ, потому что он не сильно нагружает систему дополнительной работой и вполне удовлетворительно справляется с задачей в большинстве случаев. Обычно внизу или вверху формы располагается надпись, в которую выводится дополнительная информация о текущем объекте.

Например, обработчик события ПриАктивизацииСтроки в форме списка справочника Номенклатура:

Копировать в буфер обмена
Процедура СправочникСписокПриАктивизацииСтроки(Элемент)
	ОтборТовар = Новый Структура("Номенклатура", Элемент.ТекущаяСтрока);
 	тзОстатки = РегистрыНакопления.ОстаткиНоменклатуры.Остатки(РабочаяДата, ОтборТовар);
	Если тзОстатки.Количество() > 0 Тогда
              ЭлементыФормы.тКоличество.Заголовок = тзОстатки[0].Количество;
	Иначе  
              ЭлементыФормы.тКоличество.Заголовок = 0;
	КонецЕсли;  
КонецПроцедуры

Когда же информация требуется сразу по нескольким строкам списка, вообще без щелчков мыши, то остается последний способ.

4-й способ. Обработчик события ПриВыводеСтроки.

Событие ПриВыводеСтроки вызывается всякий раз, когда система формирует строки табличного поля. Это происходит при открытии списка, его прокрутке (формируются новые строки), при выборе группы (родителя), при нажатии на кнопку "Обновить текущий список" и т.д. При простой перерисовке формы (например, одна форма была перекрыта другой), данное событие не возникает.

ВНИМАНИЕ. В версии 1С:Предприятия 8 в колонке табличного поля не может располагаться выражение на встроенном языке! Для решения подобных задач можно использовать событие ПриВыводеСтроки.

Следующий пример демонстрирует получение связанной информации по элементам справочника из периодического регистра сведений:

Копировать в буфер обмена
Процедура СправочникСписокПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)
	Если Элемент.Колонки.Статус.Видимость Тогда
		ОтборПредмет = Новый Структура("Предмет", ДанныеСтроки.Ссылка);
		Статус = РегистрыСведений.СтатусыПредметов.ПолучитьПоследнее(РабочаяДата,ОтборПредмет).Статус;
		ОформлениеСтроки.Ячейки.Статус.УстановитьТекст(?(Статус.Пустая(), "Свободно", Статус));
	КонецЕсли;
КонецПроцедуры

В обработчике события ПриВыводеСтроки не рекомендуется всякий раз обращаться к остаткам регистров, выполнять сложные запросы и другие действия, поскольку это может сильно замедлить работу со списком. По крайней мере надо стремиться минимизировать такие обращения.

Непосредственно перед алгоритмом выборки информации желательно проверить, включена ли колонка, как сделано в вышеприведенном примере, потому что пользователь может ее скрыть штатными средствами платформы и вправе рассчитывать на то, что скорость работы со списком увеличится.

Кэширование данных средствами встроенного языка

В некоторых случаях для ускорения работы со списком можно организовать кэширование средствами встроенного языка, при котором уже выбранная из базы данных информация сохраняется в памяти (например, в объекте типа "Соответствие" или "ТаблицаЗначений"), а при последуещем формировании строки информация выбирается из импровизированного кэша, а не из базы данных.

Ниже приведен пример кэширования с использованием объекта "Соответствие":

Копировать в буфер обмена
Перем Статусы; //переменная модуля формы списка
Процедура СправочникСписокПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)
	Если Элемент.Колонки.Статус.Видимость Тогда //проверяем видимость колонки Статус

		Предмет = ДанныеСтроки.Ссылка;
		Если Статусы[Предмет] = Неопределено Тогда //если в кэше нужной записи нет
                        //считываем статус предмета из базы данных   
  			Статус = РегистрыСведений.СтатусыПредметов.ПолучитьПоследнее(РабочаяДата,Новый Структура("Предмет",Предмет)).Статус;
  			Статусы[Предмет] = ?(НЕ Статус.Пустая(), Статус, Перечисления.СтатусПредмета.Свободно); //добавляем в кеш
  		КонецЕсли; 
		ОформлениеСтроки.Ячейки.Статус.УстановитьТекст(Статусы[Предмет]); //берем статус из кеша

	КонецЕсли;
КонецПроцедуры
  
Статусы = Новый Соответствие;

По мере работы со списком справочника (его прокрутке, при переходах по группам) в соответствие "Статусы" добавляются все новые и новые элементы. Но следует понимать, что информация в кэше может устареть, поэтому нужно иметь способ его периодически обновлять. Конечно, при закрытии окна переменная модуля формы "Статусы" будет уничтожена и кэш полностью очистится. Но более эргономичным решением будет специальная кнопка "Обновить полностью", доступная пользователю, или другой вариант — изменение алгоритма работы стандартной кнопки "Обновить текущий список" . Т.е. вид кнопки будет стандартный, но в алгоритме будет очищаться кэш и затем вызываться метод "Обновить()" текущей формы:

Копировать в буфер обмена
Процедура ОбновитьПолностью()
	Статусы = Новый Соответствие;
	ЭтаФорма.Обновить();
КонецПроцедуры